#
# CMake project file for cluster analysis from WHAM for single-chain proteins  
# 

enable_language (Fortran)

#================================
# Set source file lists
#================================
set(UNRES_CLUSTER_WHAM_SRC0 
 clust_data.F90
 ../wham/wham_data.F90
 ../unres/data/names.F90
 ../unres/data/io_units.F90
 ../unres/data/calc_data.F90
 ../unres/data/compare_data.F90
 ../unres/data/control_data.F90
 ../unres/data/energy_data.F90
 ../unres/data/geometry_data.F90
 ../unres/data/map_data.F90
 ../unres/data/MCM_data.F90
 ../unres/data/MD_data.F90
 ../unres/data/minim_data.F90
 ../unres/data/MPI_data.F90
 ../unres/data/comm_local.F90
 ../unres/math.F90
 ../unres/geometry.F90
 ../unres/io_base.F90
 ../unres/energy.F90
 ../unres/control.F90
 ../unres/io_config.F90
 ../unres/regularize.F90
 ../wham/io_wham.F90
 ../wham/conform_compar.F90
 ../wham/work_partition.F90
 probabl.F90
 track.F90
 hc.F90
 io_clust.F90
 cluster.F90
)


#================================================
# Set compiler flags for different sourcefiles  
#================================================
if (Fortran_COMPILER_NAME STREQUAL "ifort")
  set (CMAKE_Fortran_FLAGS_RELEASE " ")
  set (CMAKE_Fortran_FLAGS_DEBUG   "-O0 -g -traceback")     
  set(FFLAGS0 "-CB -g -fpp -mcmodel=medium -shared-intel -ip " )
elseif (Fortran_COMPILER_NAME STREQUAL "gfortran")
  set(FFLAGS0 "-std=legacy -mcmodel=medium " )
elseif (Fortran_COMPILER_NAME STREQUAL "pgF90")
  set(FFLAGS0 "-mcmodel=medium -Mlarge_arrays " )
else ()
  set(FFLAGS0 "-mcmodel=medium " )
endif (Fortran_COMPILER_NAME STREQUAL "ifort")

#=========================================
# Add MPI compiler flags
#=========================================
if(UNRES_WITH_MPI)
  set(FFLAGS0 "${FFLAGS0} -I${MPI_Fortran_INCLUDE_PATH}")
endif(UNRES_WITH_MPI)

set_property(SOURCE ${UNRES_CLUSTER_WHAM_SRC0} PROPERTY COMPILE_FLAGS ${FFLAGS0} )

#=========================================
#  Settings for GAB force field
#=========================================
if(UNRES_MD_FF STREQUAL "GAB" )
   # set preprocesor flags   
   set(CPPFLAGS "PROCOR  -DSPLITELE -DCRYST_BOND  -DCRYST_THETA -DCRYST_SC  -DSCCORPDB" )

#=========================================
#  Settings for E0LL2Y force field
#=========================================
elseif(UNRES_MD_FF STREQUAL "E0LL2Y")
   # set preprocesor flags   
   set(CPPFLAGS "PROCOR  -DSPLITELE -DSCCORPDB" )
elseif(UNRES_MD_FF STREQUAL "NEWCORR")
  # set preprocesor flags   
  set(CPPFLAGS "PROCOR -DUNRES -DISNAN -DSPLITELE -DLANG0  -DNEWCORR -DCORRCD" )
elseif(UNRES_MD_FF STREQUAL "4P")
  set(CPPFLAGS "SPLITELE -DLANG0 -DCRYST_BOND -DCRYST_THETA -DCRYST_SC -DSCCORPDB" )
endif(UNRES_MD_FF STREQUAL "GAB")

#=========================================
# Additional flags
#=========================================
set(CPPFLAGS "${CPPFLAGS} -DUNRES -DISNAN -DCLUSTER" )

#=========================================
# Compiler specific flags
#=========================================
if (Fortran_COMPILER_NAME STREQUAL "ifort")
  # Add ifort preprocessor flags
  set(CPPFLAGS "${CPPFLAGS} -DPGI") 
elseif (Fortran_COMPILER_NAME STREQUAL "f95")
  # Add new gfortran flags
  set(CPPFLAGS "${CPPFLAGS} -DG77") 
elseif (Fortran_COMPILER_NAME STREQUAL "gfortran")
  # Add old gfortran flags
  set(CPPFLAGS "${CPPFLAGS} -DG77") 
elseif (Fortran_COMPILER_NAME STREQUAL "pgf90")
  set(CPPFLAGS "${CPPFLAGS} -DPGI")
  FILE(COPY ${CMAKE_SOURCE_DIR}/source/isnan_pgi.f DESTINATION ${CMAKE_CURRENT_BINARY_DIR} )
  list(APPEND UNRES_CLUSTER_WHAM_SRC0 ${CMAKE_CURRENT_BINARY_DIR}/isnan_pgi.f)
  set(CMAKE_EXE_LINKER_FLAGS "-Bdynamic")
endif (Fortran_COMPILER_NAME STREQUAL "ifort")


#=========================================
# System specific flags
#=========================================
if(${CMAKE_SYSTEM_NAME} MATCHES "Linux")
  set(CPPFLAGS "${CPPFLAGS} -DLINUX") 
endif(${CMAKE_SYSTEM_NAME} MATCHES "Linux")

#=========================================
# Add MPI preprocessor flags
#=========================================
if (UNRES_WITH_MPI)
  set(CPPFLAGS "${CPPFLAGS} -DMP -DMPI") 
endif(UNRES_WITH_MPI)


#=========================================
# Apply preprocesor flags to *.F files
#=========================================
set_property(SOURCE ${UNRES_CLUSTER_WHAM_SRC0} PROPERTY COMPILE_DEFINITIONS ${CPPFLAGS} )  


#========================================
#  Setting binary name
#========================================
set(UNRES_CLUSTER_WHAM_BIN "cluster_wham_${Fortran_COMPILER_NAME}_MPI_${UNRES_MD_FF}.exe")

#set_property(SOURCE proc_proc.c PROPERTY COMPILE_DEFINITIONS "LINUX -DPGI" )  

#=========================================
# Set full unres CLUSTER sources
#=========================================
set(UNRES_CLUSTER_WHAM_SRCS ${UNRES_CLUSTER_WHAM_SRC0})

#=========================================
# Build the binary
#=========================================
add_executable(UNRES_CLUSTER_WHAM_BIN ${UNRES_CLUSTER_WHAM_SRCS} )
set_target_properties(UNRES_CLUSTER_WHAM_BIN PROPERTIES OUTPUT_NAME ${UNRES_CLUSTER_WHAM_BIN})
set_property(TARGET UNRES_CLUSTER_WHAM_BIN PROPERTY RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin )

#=========================================
# Link libraries
#=========================================
# link MPI libraries
if(UNRES_WITH_MPI)
  target_link_libraries( UNRES_CLUSTER_WHAM_BIN ${MPI_Fortran_LIBRARIES} )
endif(UNRES_WITH_MPI)
# link libxdrf.a 
target_link_libraries( UNRES_CLUSTER_WHAM_BIN xdrf )

#=========================================
# Install Path
#=========================================
install(TARGETS UNRES_CLUSTER_WHAM_BIN DESTINATION ${CMAKE_INSTALL_PREFIX})


#=========================================
# TESTS 
#=========================================

#  MESSAGE (STATUS "${MPI_Fortran_LIBRARIES}")
  if ("${MPI_Fortran_LIBRARIES}"  MATCHES "lam")
     MESSAGE (STATUS "LAM MPI library detected")
     set (boot_lam "-boot")
  else()
     set (boot_lam "")
  endif()

  if (UNRES_SRUN)
   set (np "-n")
   set (mpiexec "srun")
  elseif(UNRES_MPIRUN)
   set (np "-np")
   set (mpiexec "mpirun")
  else()
   set (np "-np")
   set (mpiexec "mpiexec")
  endif()

FILE(WRITE ${CMAKE_CURRENT_BINARY_DIR}/scripts/cluster_wham_mpi_E0LL2Y.sh
"#!/bin/sh
export POT=GB
export INPUT=$1
export INTIN=1L2Y_wham
export OUTPUT=1L2Y_clust
export PDB=CART
export COORD=CX
export PRINTCOOR=PRINT_PDB
#-----------------------------------------------------------------------------
CLUSTER_WHAM_BIN=${CMAKE_BINARY_DIR}/bin/${UNRES_CLUSTER_WHAM_BIN}
#-----------------------------------------------------------------------------
DD=${CMAKE_SOURCE_DIR}/PARAM
export BONDPAR=$DD/bond_AM1.parm
export THETPAR=$DD/theta_abinitio.parm
export ROTPAR=$DD/rotamers_AM1_aura.10022007.parm
export TORPAR=$DD/torsion_631Gdp.parm
export TORDPAR=$DD/torsion_double_631Gdp.parm
export ELEPAR=$DD/electr_631Gdp.parm
export SIDEPAR=$DD/scinter_$POT.parm
export FOURIER=$DD/fourier_opt.parm.1igd_hc_iter3_3
export SCPPAR=$DD/scp.parm
export SCCORPAR=$DD/sccor_am1_pawel.dat
export THETPARPDB=$DD/thetaml.5parm
export ROTPARPDB=$DD/scgauss.parm
export PATTERN=$DD/patterns.cart
export CONTFUNC=GB
export SIDEP=$DD/contact.3.parm
export SCRATCHDIR=.
#-----------------------------------------------------------------------------
echo CTEST_FULL_OUTPUT
${mpiexec} ${boot_lam} ${np} $2 $CLUSTER_WHAM_BIN 
./cluster_wham_check.sh $1 
")

#
# File permissions workaround
#
FILE(	COPY ${CMAKE_CURRENT_BINARY_DIR}/scripts/cluster_wham_mpi_E0LL2Y.sh 
	DESTINATION ${CMAKE_CURRENT_BINARY_DIR}
	FILE_PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_EXECUTE WORLD_READ WORLD_EXECUTE
)

FILE(COPY ${CMAKE_SOURCE_DIR}/ctest/cluster_wham_check.sh
        DESTINATION ${CMAKE_CURRENT_BINARY_DIR} 
        FILE_PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_EXECUTE WORLD_READ WORLD_EXECUTE
)

FILE(COPY ${CMAKE_SOURCE_DIR}/ctest/1L2Y_clust.inp
        DESTINATION ${CMAKE_CURRENT_BINARY_DIR} )

FILE(COPY ${CMAKE_SOURCE_DIR}/ctest/1L2Y_wham.cx
        DESTINATION ${CMAKE_CURRENT_BINARY_DIR} )

FILE(COPY ${CMAKE_SOURCE_DIR}/ctest/1L2Y.pdb
        DESTINATION ${CMAKE_CURRENT_BINARY_DIR} )


if(UNRES_MD_FF STREQUAL "E0LL2Y")
    add_test(NAME CLUSTER_WHAM_remd COMMAND sh ${CMAKE_CURRENT_BINARY_DIR}/cluster_wham_mpi_E0LL2Y.sh 1L2Y_clust 2 )
endif(UNRES_MD_FF STREQUAL "E0LL2Y")
